COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "Print Pony Data File"
C00004 ENDMK
C⊗;
BEGIN "Print Pony Data File"
INTEGER I,J,K,L,BRCHR,IEOF,OEOF,TOTAL;
STRING S;

OPEN(1,"DSK",'10,2,0,200,BRCHR,IEOF);
OPEN(2,"DSK",0,0,2,200,BRCHR,OEOF);

DO BEGIN
	OUTSTR("Input file: ");
	S←INCHWL;
	LOOKUP(1,S,IEOF);
	IF IEOF THEN OUTSTR("Lookup failed.  ");
	END
UNTIL ¬IEOF;
DO BEGIN
	OUTSTR("Output file: ");
	S←INCHWL;
	ENTER(2,S,OEOF);
	IF OEOF THEN OUTSTR("Enter failed.  ");
	END
UNTIL ¬OEOF;

SETFORMAT(4,7);
TOTAL←0;
WHILE TRUE DO BEGIN
	I←WORDIN(1); IF IEOF THEN DONE;
	J←WORDIN(1);
	K←I LAND '777777000000;		COMMENT USER NAME;
	I←I LAND '777777;		COMMENT DATE;
	L←J LAND '777777000000;		COMMENT ITEM NAME;
	J←J LAND '777777;		COMMENT PRICE;
	IF J LAND '400000 THEN J←J LOR '777777000000;  COMMENT CREDIT;
	TOTAL←TOTAL+J;
	OUT(2,CVXSTR(K)&CVS(I)&'11&CVXSTR(L)&CVS(J)&'15&'12);
	END;
SETFORMAT(-2,0);
OUT(2,"Total charges: "&CVS(TOTAL DIV 100)&"."&CVS(TOTAL MOD 100)&'15&'12);
RELEASE(1);
RELEASE(2);
END;