COMMENT ⊗   VALID 00004 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002		TITLE	LODREQ	CHASE DOWN LOAD MODULE AND LIBRARY REQUESTS
C00005 00003	LODREQ:	RESET
C00011 00004	GETCMD:
C00017 ENDMK
C⊗;
	TITLE	LODREQ	CHASE DOWN LOAD MODULE AND LIBRARY REQUESTS
COMMENT ⊗
	Command string is similar to loader format:
		<out file>←<in file>,<in file>, ... ,<in file><alt>
	"Switches" are not allowed.  
⊗


?P←17
FF←0
A←1
B←2
C←3
D←4
T0←5
T1←6
T2←10
T3←11
T4←12
 T←T0
Q←13		;LAST,,FIRST	FILE DESCRIPTOR BLOCKS TO BE PROCESSED
DON←14		;FILES ALREADY PROCESSED
L←15		;LOW LIMIT OF CORE ALLOCATION
SR←16		;USED FOR FASTER SKIP RETURNS

IC←0		;CHANNELS
OC←1
EOF←←20000

$LNK←←0		;OFFSETS IN REQUEST BLOCKS
$EXT←←1
$FIL←←2
$PPN←←3
$DEV←←4
$LEN←←5		;LENGTH OF BLOCK

.LOD←←16	;LOADER BLOCK TYPES
.LIB←←17
.IDX←←14

EXTERNAL .JBFF,.JBREL

GETLCOR:MOVE	L,.JBFF
	MOVEI	T,-1+$LEN(L)	;HIGHEST ADDRESS WE NEED
GETCOR:
	CAMG	T,.JBREL
	 POPJ	P,		;IF WE ALREADY HAVE IT
	CORE	T,
	 JRST	[CORERR:OUTSTR	[ASCIZ/
CORE failed./]
		HALT	.
		POPJ	P,]
	POPJ	P,

FILERR:
	OUTSTR	(A)		;WHO FAILED
	PUSH	P,[OUTCHR C]	;DELIVER TO TERMINAL
	PUSHJ	P,FILPRT
	RELEASE	IC,
	RELEASE	OC,
	HALT	.
	JRST	LODREQ

FILPRT:				;-1(P)=INSTR TO XCT TO DISPOSE OF CHAR IN C
	MOVE	D,-1(P)		;INSTR TO XCT TO DISPOSE OF CHAR IN C
	MOVE	B,$DEV(Q)
	JUMPE	B,FIL.1		;NULL DEVICE
	PUSHJ	P,SIXPRT
	MOVEI	C,":"
	XCT	D
FIL.1:	MOVE	B,$FIL(Q)
	PUSHJ	P,SIXPRT
	HLLZ	B,$EXT(Q)
	JUMPE	B,FIL.3		;NULL EXTENSION (IMPLIES .REL)
	MOVEI	C,"."
	XCT	D
	PUSHJ	P,SIXPRT
FIL.3:	SKIPN	B,$PPN(Q)
	 JRST	FIL.2		;NULL PPN
	MOVEI	C,"["
	XCT	D
	HLLZ	B,$PPN(Q)
	JRST	.+2		;LEFT JUSTIFY
	LSH	B,6
	TLNN	B,770000
	 JRST	.-2
	PUSHJ	P,SIXPRT
	MOVEI	C,","
	XCT	D
	HRLZ	B,$PPN(Q)
	JRST	.+2		;LEFT JUSTIFY
	LSH	B,6
	TLNN	B,770000
	 JRST	.-2
	PUSHJ	P,SIXPRT
	MOVEI	C,"]"
	XCT	D
FIL.2:	SUB	P,[2,,2]
	JRST	@2(P)
	
SIXPRT:	SETZ	C,		;SIXBIT IN B, STOP AFTER LAST NON-BLANK
	ROTC	B,6
	ADDI	C,40
	XCT	D
	JUMPN	B,SIXPRT
	POPJ	P,
LODREQ:	RESET
	SETZM	BUFLOC#
	SETZ	T,
	DSKPPN	T,
	MOVEM	T,ALIAS#	;WILL BE USED AS DEFAULT PPN
	MOVE	P,[IOWD LPDL,PDL]
	SETZ	DON,		;EMPTY
	PUSHJ	P,GETCMD

ISDUP:
	EXCH	DON,(Q)		;DON←2ND ON Q, TOP OF QUEUE←FIRST ON DONE LIST
	EXCH	DON,Q		;Q←2ND ON Q, DON←NEW HEAD OF DONE LIST
	HLL	Q,DON		;CARRY AROUND LAST OF Q
	TRNN	Q,-1
	 JRST	FIN		;REQUEST QUEUE IS EMPTY
	SKIPN	T3,$DEV(Q)
	MOVSI	T3,'DSK'		;FILL IN DEFAULTS
	SKIPN	T4,$EXT(Q)
	MOVSI	T4,'REL'
	SKIPN	T2,$PPN(Q)
	MOVE	T2,ALIAS
	MOVE	T1,$FIL(Q)
	MOVEI	T,DON
	JRST	DUPCHK
DUPTOP:	CAMN	T1,$FIL(T)
	CAME	T2,$PPN(T)
	 JRST	DUPCHK
	CAMN	T3,$DEV(T)
	 JRST	ISDUP
DUPCHK:	HRRZ	T,(T)
	JUMPN	T,DUPTOP
ISNEW:
	PUSHJ	P,CRLF
	PUSH	P,[PUSHJ P,CHROUT]
	PUSHJ	P,FILPRT	;IDENTIFY THIS FILE
	MOVEM	T3,$DEV(Q)	;BE SURE THESE ARE WELL DEFINED
	MOVEM	T2,$PPN(Q)
	MOVEM	T3,DEVOPN	;PREPARE TO READ THE FILE
	OPEN	IC,OPNADR
	 JRST	[MOVEI	A,[ASCIZ/
OPEN failed./]
		JRST	FILERR]
	MOVEM	T1,LOKADR	;FILENAME
	MOVEM	T4,LOKADR+1	;EXTENSION
	MOVEM	T2,LOKADR+3	;PPN
	LOOKUP	IC,LOKADR
	 JRST	[MOVEI	A,[ASCIZ/
LOOKUP failed./]
		JRST	FILERR]

	SKIPN	T,BUFLOC	;PUT BUFFER RING IN SAME PLACE ALL THE TIME
	 MOVE	T,.JBFF
	EXCH	T,.JBFF
	INBUF	IC,=18		;TRACK AT A TIME AT STANFORD
	SKIPE	BUFLOC
	 JRST	BL.1
	MOVEM	T,BUFLOC	;WAS FIRST TIME, SO BUFLOC← OLD .JBFF
	JRST	NXTTAB		;AND LEAVE .JBFF ALONE
BL.1:	MOVEM	T,.JBFF		;NOT FIRST TIME, RESTORE .JBFF
NXTTAB:
	PUSHJ	P,WORDIN	;RETURN WORD IN C
	 JRST	ISDUP		;END OF FILE
	JUMPE	C,NXTTAB	;ZERO WORDS ARE A PAIN
	HLRZ	T,C		;TABLE TYPE
	CAIE	T,.LOD
	CAIN	T,.LIB
	 JRST	QBLOCK		;FOUND ONE WE WANT

				;DISCARD. TABLE TYPE IN T, "COUNT" IN RH(C)
	CAIN	T,.IDX		;INDEX BLOCKS ARE SPECIAL
	 JRST	[MOVEI	T,1	;ONE WORD FOR HEADER
		JRST	DIS.1]	;PLUS COUNT
	MOVEI	T,=17+=18(C)	;;=17 TO CORRECT FOR RELOC WORDS, =18 FOR HEADER
	IDIVI	T,=18
DIS.1:	ADDI	T,-1(C)		;-1+TOTAL SIZE THIS TABLE
DIS.3:
	ADDM	T,IBUF+1	;ADVANCE BYTE POINTER
	SUB	T,IBUF+2	;SUBRTRACT (#LEFT +1)
	AOJGE	T,DIS.2		;THIS BUFFER RAN OUT
	MOVNI	T,-1(T)		;NEW COUNT
	HRRZM	T,IBUF+2	;NEW COUNT
	JRST	NXTTAB		;TRY AGAIN
DIS.2:
	SETZM	IBUF+2		;FORCE EARLY TERMINATION
	JUMPE	T,NXTTAB	;RAN OUT EXACTLY
	PUSHJ	P,WORDIN	;ADVANCE BUFFER, READ ONE WORD
	 JRST	[TABERR:MOVEI	A,[ASCIZ/
File format error./]
		PUSHJ	P,FILERR]
	SOJG	T,DIS.3		;CORRECT FOR WORD READ, TRY AGAIN
	JRST	NXTTAB		;WAS ONLY ONE WORD OVER

QBLOCK:
	MOVEI	T4,(T)		;SAVE TABLE TYPE
	MOVEI	FF,(C)		;# DATA WORDS
	PUSHJ	P,WORDIN	;IGNORE RELOC WORD
	 JRST	TABERR
QBLK.1:
	PUSHJ	P,GETLCOR
	PUSHJ	P,WORDIN	;READ THE ENTRIES INTO BLOCK AT  (L)
	 JRST	TABERR
	MOVEM	C,$FIL(L)
	PUSHJ	P,WORDIN
	 JRST	TABERR
	MOVEM	C,$PPN(L)
	PUSHJ	P,WORDIN
	 JRST	TABERR
	MOVEM	C,$DEV(L)
	SETZM	$EXT(L)

	HLRZ	T,Q		;BASE OF CURRENT LAST ELEMENT
	HRRZM	L,$LNK(T)	;PUT THIS ONE AT END
	SETZM	$LNK(L)
	HRLI	Q,(L)
	MOVEI	L,$LEN
	ADDM	L,.JBFF
	PUSHJ	P,CRLF
	CAIE	T4,.LIB
	 JRST	QBLK.2
	MOVEI	C," "
	PUSHJ	P,CHROUT
	MOVEI	C," "
	PUSHJ	P,CHROUT
	MOVEI	C," "
	PUSHJ	P,CHROUT
	MOVEI	C,"L"
	PUSHJ	P,CHROUT
	MOVEI	C,"I"
	PUSHJ	P,CHROUT
	MOVEI	C,"B"
	PUSHJ	P,CHROUT
QBLK.2:
	MOVEI	C,11
	PUSHJ	P,CHROUT	;INDENT REQUIRED FILE
	MOVS	Q,Q		;PRINT THE FILE NAME AT END OF QUEUE
	PUSH	P,[PUSHJ P,CHROUT]
	PUSHJ	P,FILPRT
	MOVS	Q,Q		;RESTORE Q TO LAST,,FIRST
	SUBI	FF,3
	JUMPN	FF,QBLK.1	;LOOP FOR ALL FILES IN TABLE
	JRST	NXTTAB		;WE ATE THIS ONE THE HARD WAY

FIN:	RELEASE	IC,
	RELEASE	OC,
	OUTSTR	[ASCIZ/
/]
	JRST	LODREQ
GETCMD:
define ch.alt<175>	;favorite flavor of altmode
	OUTCHR	["*"]
	MOVSI	T,'DSK'	;DEFAULT DEVICE
	MOVEM	T,DEVNAM
	PUSH	P,[0]		;DEFAULT EXTENSION
	PUSHJ	P,GETFIL	;TRY FOR LISTING FILE
	 JRST	[SKIPN	T,DEVNAM	;DEVICE ONLY
		TTYOUT:MOVSI	T,'TTY'
		MOVEM	T,DEVNAM	;OUTPUT DEVICE NAME
		MOVSI	T,'F  '
		MOVEM	T,FILNAM
		JRST	.+1]
	CAIE	1,"←"
	CAIN	1,"="
	JRST	.+2
	 JRST	[MOVEI 1,"←"↔JRST TTYOUT]
	MOVE	T,DEVNAM
	MOVEM	T,OUTDEV
	OPEN	OC,OPNOUT
	 JRST	[OUTSTR	[ASCIZ/
Cannot OPEN output device./]
		HALT	.
		JRST	.+1]
	MOVE	T,FILNAM
	MOVEM	T,ONAME
	MOVE	T,EXTION
	MOVEM	T,ONAME+1
	SETZM	ONAME+2
	MOVE	T,PPPN
	MOVEM	T,ONAME+3
	ENTER	OC,ONAME
	 JRST	[OUTSTR	[ASCIZ/
Cannot ENTER output file./]
		HALT	.
		JRST	.+1]

	PUSHJ	P,GETLCOR
	MOVSI	Q,(L)		;INITIAL QUEUE IS EMPTY
	HRRI	Q,(L)
	SETZM	(Q)
	MOVEI	L,$LEN
	ADDM	L,.JBFF
GETLUP:	PUSH	P,['REL   ']
	MOVSI	T,'DSK'
	MOVEM	T,DEVNAM
	PUSHJ	P,GETFIL
	 JRST	[OUTSTR	[ASCIZ/
Bad file spec./]
		JRST	GETCMD]
	PUSHJ	P,GETLCOR
	MOVE	T,FILNAM
	MOVEM	T,$FIL(L)
	MOVE	T,EXTION
	MOVEM	T,$EXT(L)
	MOVE	T,DEVNAM
	MOVEM	T,$DEV(L)
	MOVE	T,PPPN
	MOVEM	T,$PPN(L)
	HLRZ	T4,Q		;LAST ON QUEUE
	HRRZM	L,(T4)		;LINK THIS ONE TO CURRENT LAST ONE
	SETZM	(L)		;ZERO OUT LINK
	HRLI	Q,(L)
	MOVEI	L,$LEN
	ADDM	L,.JBFF
	CAIE	1,CH.ALT
	 JRST	GETLUP		;CONTINUE UNTIL ALTMODE
	POPJ	P,
	
	
;GET FILE SPEC FROM TTY LINE (STOLEN FROM GRUMP[X,AIL])
;uses 0,1,2,3,4
;called via
;	push	p,[<default extension>]
;	pushj	p,getfil
;	 <no file name, or device only specified>
;	<success return>	;char which broke the scan in is 1
begin getfil
	opdef go [jrst]
	define pop0j <popj p,>
	define pop2j <jrst[sub p,[2,,2]↔jrst @2(p)]>
	define pop3j <jrst[sub p,[3,,3]↔jrst @3(p)]>
	define arg2 <-1(p)>
↑getfil:
	SETZM FILNAM↔SETZM EXTION↔SETZM SQCNT#	;BRACKET NEST DEPTH
	SETZM EXTION+1↔SETZM PPPN
	MOVE 4,[POINT 6,FILNAM,-1]↔MOVEI 2,6
	INCHWL 1↔CAIN 1,15↔GO[INCHWL↔POP2J]↔AOS(P)
	JRST L+1
L:	INCHWL 1
	CAILE 1,"z"↔POP2J
	CAIL 1,"a"↔SUBI 1,40		;CONVERT LOWER CASE
	CAIN 1,":"↔GO[MOVE 4,FILNAM↔MOVEM 4,DEVNAM↔SOS (P)↔GO GETFIL]
	CAIN 1,"."↔GO[MOVE 4,[POINT 6,EXTION,-1]↔MOVEI 2,3↔GO L]
	CAIN 1,"["↔GO[AOS SQCNT↔MOVE 4,[POINT 6,PPPN,-1]  ↔MOVEI 2,3↔GO L]
	CAIN 1,","↔GO[SKIPN SQCNT↔JRST EOL+1	;TOP-LEVEL COMMA
			HLRZ PPPN
		      PUSHJ P,[PPJUST:	JUMPE [OUTSTR[ASCIZ/BAD P,PN
/]↔						CLRBFI↔SOS -1(P)↔POP3J]	
		   	 		TRNE 77↔POP0J↔LSH -6↔GO PPJUST]
		      HRLM PPPN↔MOVE 4,[POINT 6,PPPN,17]↔MOVEI 2,3↔GO L]
	CAIN 1,"]"↔GO[SOS SQCNT↔HRRZ PPPN↔PUSHJ P,PPJUST
		   HRRM PPPN↔INCHWL 1↔GO FINQ]
FINQ:	CAIN 1,15↔GO EOL			;END OF THE LINE.
	CAIN 1,12↔POP2J
	 CAIE 1,"←"
	CAIN 1,"="↔GO EOL+1	;SEPARATING EQUALS OR LEFT ARROW
	CAIN 1,CH.ALT↔GO EOL+1	;TERMINATING ALTMODE
	CAIG 1," "↔GO L	;IGNORE GARBAGE.
	SOJL 2,L↔SUBI 1,40↔IDPB 1,4↔GO L

EOL:	INCHWL 2
	SKIPN 2,EXTION↔MOVE 2,ARG2↔MOVEM 2,EXTION
	POP2J
BEND


WORDIN:	SOSG	IBUF+2
	IN	IC,
	JRST	WORD.1
	STATZ	IC,EOF
	POPJ	P,		;YES EOF, NO SKIP RETURN
	MOVEI	A,[ASCIZ/
IN error./]
	JRST	FILERR
WORD.1:	ILDB	C,IBUF+1
	POP	P,SR
	JRST	1(SR)


CRLF:	MOVEI	C,15
	PUSHJ	P,CHROUT
	MOVEI	C,12
CHROUT:	SOSG	OBUF+2		;PUT CHAR IN  C  INTO OUTPUT BUFFER
	OUT	OC,
	JRST	CHROU1
	OUTSTR	[ASCIZ/
OUT failed./]
	HALT	.
CHROU1:	IDPB	C,OBUF+1
	POPJ	P,

OPNADR:	14	;BUFFERED BINARY
DEVOPN:	BLOCK	1
	0,,IBUF	;HEADER AT IBUF

OPNOUT:	0	;ASCII CHARACTERS
OUTDEV:	BLOCK	1
	OBUF,,0	;HEADER AT OBUF

DEVNAM:	0
FILNAM:	0	;FILE NAME.
EXTION:	0	;EXTENSION.
	0
PPPN:	0	;PROJECT-PROGRAMMER.

IBUF:	BLOCK	3
LOKADR:	BLOCK	4

OBUF:	BLOCK 3
ONAME:	BLOCK	4
LPDL←←10
	PDL:	BLOCK LPDL

	END	LODREQ