COMMENT ⊗   VALID 00007 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	Individual statement interpreters }
C00028 00003	{ Externally defined routines: }
C00031 00004	procedure doEnable external
C00032 00005	procedure doDisable external
C00033 00006	procedure doAffix external
C00039 00007	procedure doUnfix external
C00040 ENDMK
C⊗;
{$NOMAIN	Individual statement interpreters }

const

  (* Constants from EDIT *)

  maxLines = 28;
  maxPPLines = 12;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

(* Random type declarations for OMSI/SAIL compatibility *)

type
  byte = 0..255;	(* doesn't really belong here, but... *)
  ascii = char; 
  atext = text;

{ Define all the pointer types here }

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑message;

(* This one is used whenever a pointer is needed for which the 	*)
(* definition is missing from this file; naturally, all 	*)
(* pointers use the same space 					*)

dump = ↑integer;
token = array[1..4] of integer;		{Uses same space as a token}
cursorp = array[1..4] of integer;	{Ditto, for cursorp}


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;

u = (used,free);
vector = record case u of
	   used: (refcnt: integer; val: array [1..3] of real);
	   free: (next: vectorp);
	 end;

trans = record case u of
	   used: (refcnt: integer; val: array [1..3,1..4] of real);
	   free: (next: transp);
	end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;



(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    affixtype,
    unfixtype:	    (frame1, frame2, byvar, atexp: nodep; rigid: boolean);
    enabletype,
    disabletype:    (cmonlab: varidefp);
    cmtype:	    (oncond: nodep; conclusion: statementp;
			deferCm, exprCm: boolean; cdef: varidefp);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: dump;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: dump);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: dump);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    cmonnode:	(cmon: statementp; errhandlerp: boolean);
    errornode:	(eexpr: nodep);
    calcnode: 	(rigid, frame1: boolean; other: framep; case tvarp: boolean of 
		    false: (tval: transp); true: (tvar: enventryp) );
	end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* definition of AL-ARM messages *)

msgtypes = (initarmscmd,calibcmd,killarmscmd,wherecmd,
	    abortcmd,stopcmd,movehdrcmd,movesegcmd,
	    centercmd,operatecmd,movedonecmd,signalcmd,
	    setccmd,forcesigcmd,forceoffcmd,biasoncmd,biasoffcmd,setstiffcmd,
	    zerowristcmd,wristcmd,gathercmd,getgathercmd,readadccmd,writedaccmd,
	    errorcmd,floatcmd,setloadcmd,
	    armmagiccmd,realcmd,vectorcmd,transcmd);

errortypes = (noerror,noarmsol,timerr,durerr,toolong,featna,
	      unkmess,srvdead,adcdead,nozind,exjtfc,paslim,nopower,badpot,devbusy,
	      baddev,timout,panicb,nocart,cbound,badparm);

message = record
	   cmd: msgtypes;
	   ok: boolean;
	   case integer of
	1:   (dev, bits, n: integer;
(*	     (dev, bits, n, evt: integer;	(* for arm code version *)
	      evt: eventp;
	      dur: real;
	      case integer of
		1: (v1,v2,v3: real);
		2: (sfac,wobble,pos: real);
		3: (val,angle,mag: real);
		4: (max,min: real);
		5: (error: errortypes));
	2:   (fv1,fv2,fv3,mv1,mv2,mv3: real);	(* may never use these... *)
	3:   (t: array [1..6] of real);
	  end;

interr = record
         case integer of
           0: (i: integer);
	   1: (err,foo: errortypes);
	 end;

listingarray = packed array [0..listinglength] of ascii;


(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
(*  lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii; *)
    dum1: array[1..260] of ascii;
    lines: array [1..maxLines] of dump; 
    ppLines: array [1..maxPPLines] of dump;	
(*  marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
*)  dum2: array[1..141] of dump;
(*  smartTerminal: boolean; 
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
*)  dum3: array[1..16] of boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
(*  nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;
*)  dum4: array[1..5] of integer;
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines: }

	(* From ALLOC *)
function newNode: nodep;					external;
procedure relNode(n: nodep);					external;

	(* From IAUX1A *)
function getVar (level, offset: byte): enventryp;		external;
function pop: nodep;						external;
procedure upTrans (var t: transp; tp: transp);			external;
function gtVarn (n: nodep): enventryp;				external;
function feval (f: framep): transp;				external;

	(* From IAUX1B *)
procedure sleep(whenV: integer);				external;
procedure cmonDisable(c: cmoncbp);				external;

	(* From IAUX2A *)
procedure affixaux (f, d: framep; cnt: integer);		external;
function unfixaux (f: framep; cnt: integer): boolean;		external;
procedure unfix (f1,f2: framep);				external;

	(* From IAUX2B *)
procedure cmonEnable(e: enventryp);				external;

	(* Arithmetic Routines *)
function ttmul (t1,t2: transp): transp; 			external;
function tinvrt (t: transp): transp; 				external;

	(* Display-related Routines *)
procedure ppLine; 						external;
procedure ppOutNow; 						external;
procedure ppChar(ch: ascii); 					external;
procedure pp5(ch: c5str; length: integer); 			external;
procedure pp10(ch: cstring; length: integer); 			external;
procedure pp10L(ch: cstring; length: integer);			external;
procedure pp20(ch: c20str; length: integer); 			external;
procedure pp20L(ch: c20str; length: integer); 			external;
procedure ppInt(i: integer); 					external;
procedure ppReal(r: real); 					external;
procedure ppStrng(length: integer; s: strngp); 			external;

procedure doEnable; external;
procedure doEnable;
 begin
 with curInt↑ do
  begin
  if spc↑.cmonlab = nil then
    if cm <> nil then cm↑.enabled := true	(* re-enabling this cmon *)
     else
      begin
      pp20L('No cmon to enable!  ',18); ppLine;
      end
   else
    begin
    with spc↑.cmonlab↑.s↑.cdef↑ do
     cmonEnable(getVar(level,offset));		(* enable cmon control block *)
    end;
  mode := 0;
  spc := spc↑.next;
  end;
 end;

procedure doDisable; external;
procedure doDisable;
 var e: enventryp;
 begin
 with curInt↑ do
  begin
  if spc↑.cmonlab = nil then
    if cm <> nil then cm↑.enabled := false	(* disabling this cmon *)
     else
      begin
      pp20L('No cmon to disable! ',19); ppLine;
      end
   else
    begin
    with spc↑.cmonlab↑.s↑.cdef↑ do
     e := getVar(level,offset);		(* get cmon control block *)
    if e↑.c↑.running then sleep(30)	(* if running wait for it to finish *)
     else
      begin
      cmonDisable(e↑.c);			(* disable it *)
      mode := 0;
      spc := spc↑.next;
      end;
    end;
  end;
 end;

procedure doAffix; external;
procedure doAffix;
 var f1, f2: framep; ev: enventryp; c1, c2: nodep; t: transp; b: boolean;
 begin
 with curInt↑ do
  begin   (* stack has subscripts for frame1, frame2 & byvar & atexp value *)
  ev := gtVarn(spc↑.frame1);	(* access variable *)
  f1 := ev↑.f;
  ev := gtVarn(spc↑.frame2);	(* access variable *)
  f2 := ev↑.f;
  if spc↑.byvar <> nil then
    ev := gtVarn(spc↑.byvar)	(* access variable *)
   else ev := nil;
  if spc↑.atexp <> nil then
    begin
    c1 := pop;			(* get at expression value *)
    t := c1↑.t;			(* save it for later *)
    relNode(c1);		(* release node *)
    end
   else t := ttmul(feval(f1),tinvrt(feval(f2)));	(* need to compute it *)
  c1 := f1↑.calcs;		(* see if frames are already affixed *)
  b := true;
  while b and (c1 <> nil) do
    if c1↑.other = f2 then b := false else c1 := c1↑.next;
  if c1 <> nil then		(* currently affixed *)
    begin
    c2 := f2↑.calcs;		(* find its mate *)
    while c2↑.other <> f1 do c2 := c2↑.next;
    if (not c1↑.tvarp) and (spc↑.byvar <> nil) then
      begin	    (* if old affixment was direct and new one isn't *)
      upTrans(c1↑.tval,nil);   (* release old trans values *)
      upTrans(c2↑.tval,nil);
      end;
    end
   else
    begin				(* get a pair of calc nodes *)
    c1 := newNode;
    c2 := newNode;
    c1↑.ntype := calcnode;		(* indicate that we're a calc *)
    c2↑.ntype := calcnode;
    c1↑.other := f2;			(* fill in other field *)
    c2↑.other := f1;
    c1↑.next := f1↑.calcs;		(* link us to list of calcs *)
    f1↑.calcs := c1;
    c2↑.next := f2↑.calcs;
    f2↑.calcs := c2;
    c1↑.tval := nil;			(* don't have a value yet *)
    c2↑.tval := nil;
    end;
  c1↑.frame1 := true;			(* say who's who *)
  c2↑.frame1 := false;
  c1↑.rigid := spc↑.rigid;		(* remember what type of affixment *)
  c2↑.rigid := spc↑.rigid;
  b := ev <> nil;			(* trans by var given? *)
  c1↑.tvarp := b;
  c2↑.tvarp := b;
  if b then
    begin				(* indirect trans pointer *)
    upTrans(ev↑.t,t);			(* store away relation trans *)
    c1↑.tvar := ev;			(* and pointers to trans var *)
    c2↑.tvar := ev;
    end
   else
    begin				(* direct trans *)
    upTrans(c1↑.tval,t);		(* store away relation trans *)
    upTrans(c2↑.tval,t);
    end;
  b := false;				(* assume no conflict *)
  if not f1↑.ftype then			(* f1 is a device *)
    if not f2↑.ftype then b := f1 <> f2	  (* f2 is also a device! *)
     else
      if f2↑.dev <> nil then b := f2↑.dev <> f1	(* f2 already dynamic *)
       else affixaux(f2,f1,1)			 (* f2 now dynamic *)
   else					(* f1 is a frame *)
    if not f2↑.ftype then		  (* f2 is a device *)
      if f1↑.dev <> nil then b := f1↑.dev <> f2	(* f1 already dynamic *)
       else affixaux(f1,f2,1)			  (* f1 now dynamic *)
     else					(* both frames *)
      if f1↑.dev <> nil then			  (* f1 is dynamic *)
	if f2↑.dev <> nil then b := f1↑.dev <> f2↑.dev (* both dynamic *)
	 else affixaux(f2,f1↑.dev,f1↑.dcntr+1)		(* f2 now dynamic *)
       else
	 if f2↑.dev <> nil then affixaux(f1,f2↑.dev,f2↑.dcntr+1); (* f1 now dynamic *)
  if b then
    begin
    pp20L('Can''t have an affixm',20); pp20('ent chain connecting',20);
    pp20(' two devices togethe',20); pp5('r!   ',2); ppLine;
    end;
  mode := 0;
  spc := spc↑.next;
  end;
 end;

procedure doUnfix; external;
procedure doUnfix;
 var f1, f2: framep; ev: enventryp;
 begin
 with curInt↑ do
  begin	(* subscripts for frame1 & frame2 on stack *)
  ev := gtVarn(spc↑.frame1);	(* access variable *)
  f1 := ev↑.f;
  ev := gtVarn(spc↑.frame2);	(* access variable *)
  f2 := ev↑.f;
  unfix(f1,f2);			(* now unfix them *)
  mode := 0;
  spc := spc↑.next;
  end;
 end;