COMMENT ⊗   VALID 00004 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	Editor: MoveOrder routine }
C00031 00003	{ Externally defined routines from elsewhere: }
C00033 00004	(* aux routine to set up evaluation order for motions: moveOrder *)
C00049 ENDMK
C⊗;
{$NOMAIN	Editor: MoveOrder routine }

(* definition of record types & global variables used by AL *)

const 

  maxLines = 28;
  maxPPLines = 12;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

type

(* random type declarations for OMSI/SAIL compatibility *)

 ascii = char;
 atext = text;
 byte = 0..255;	

(* Here are all the pointer-type definitions.  Since the various 	*)
(* records reference each other so much, we have to put them all here.	*)

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
identp = ↑ident;
tokenp = ↑token;
reswordp = ↑resword;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑integer;
linerecp = ↑linerec;


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;
vector = record  refcnt: integer; val: array [1..3] of real end;
trans = record  refcnt: integer; val: array [1..3,1..4] of real end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;


(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    progtype:	    (pcode: statementp; errors: integer);
    blocktype,
    declaretype,
    endtype,
    coendtype:	    (bcode, bparent: statementp; blkid: identp;
			level, numvars: 0..255; variables: varidefp);
    stoptype:	    (cf, clauses: nodep);
    cmtype:	    (oncond: nodep; conclusion: statementp;
			deferCm, exprCm: boolean; cdef: varidefp);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: tokenp);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: identp);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    listnode:	(lval: nodep);
    wrtnode,
    deprnode,
    apprnode,
    destnode:	(loc: nodep; code: statementp);
    byptnode,
    viaptnode:	(vlist: boolean; via,vclauses: nodep; vcode: statementp);
    durnode:	(durrel: reltypes; durval: nodep);
    velocitynode,
    sfacnode,
    wobblenode,
    swtnode:	(clval: nodep);
    ffnode:	(ff,cf: nodep; csys, pdef: boolean); (* true = world, false = hand *)
    loadnode:	(loadval,loadvec: nodep; lcsys: boolean); (* lcsys = csys above *)
    forcenode:	(ftype: forcetypes; frel: reltypes; fval, fvec, fframe: nodep);
    stiffnode:	(fv, mv, cocff: nodep);
    errornode:	(eexpr: nodep);
    gathernode:	(gbits: integer);
    cmonnode:	(cmon: statementp; errhandlerp: boolean);
	end;



(* records for parser: ident, token, resword *)

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;


tokentypes = (reswdtype, identtype, constype, comnttype, delimtype, labeldeftype,
		macpartype);

constypes = svaltype..strngtype;

reswdtypes = (stmnttype, filtype, clsetype, decltype, optype, edittype);

filtypes = (abouttype,alongtype,attype,bytype,defertype,dotype,elsetype,
		errmodestype,fromtype,handtype,intype,nonrigidlytype,rigidlytype,
		sourcefiletype,steptype,thentype,totype,untltype,viatype,
		withtype,worldtype,zeroedtype,oftype,wheretype,nowaittype,
		ontype,offtype,ppsizetype,collecttype,alltype,lextype,
		notype,righttype,lefttype,uptype,downtype,motiontype);

clsetypes = (approachtype,arrivaltype,departuretype,departingtype,durationtype,
		errortype,forcetype,forceframetype,forcewristtype,gathertype,
		nildeproachtype,nullingtype,stiffnesstype,
		torquetype,velocitytype,wobbletype,
		cwtype,ccwtype,stopwaittimetype,angularvelocitytype,
		respecttype,elbowtype,shouldertype,fliptype,lineartype,
		jointspacetype,loadtype);

edittypes = (getcmd,savecmd,insertcmd,renamecmd,startcmd,gocmd,proceedcmd,
		stepcmd,sstepcmd,nstepcmd,gstepcmd,executecmd,setcmd,tracecmd,
		breakcmd,unbreakcmd,tbreakcmd,definecmd,markcmd,unmarkcmd,
		popcmd,atcmd,calibratecmd);

token = record
	  next: tokenp;
	  case ttype: tokentypes of
constype:   (cons: nodep);
comnttype:  (len: integer; str: strngp);
delimtype:  (ch: ascii);
reswdtype:  (case rtype: reswdtypes of
	stmnttype: (stmnt: stmntypes);
	filtype:   (filler: filtypes);
	clsetype:  (clause: clsetypes);
	decltype:  (decl: datatypes);
	optype:	   (op: exprtypes);
	edittype:  (ed: edittypes) );
identtype:  (id: identp);
labeldeftype: (lab: varidefp);
macpartype: (mpar: varidefp);
	end;


resword = record
	  next: reswordp;
	  length: integer;
	  name: strngp;
	  case rtype: reswdtypes of
	stmnttype:  (stmnt: stmntypes);
	filtype:    (filler: filtypes);
	clsetype:   (clause: clsetypes);
	decltype:   (decl: datatypes);
	optype:	    (op: exprtypes);
	edittype:  (ed: edittypes);
	  end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* print related records: *)

cursorp = record
	  cline,ind: integer;
	  case stmntp: boolean of
  true:    (st: statementp);
  false:   (nd: nodep);
	 end;

linerec = record
	next: linerecp;
	start,length: integer
       end;

listingarray = packed array [0..listinglength] of ascii;



(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
    lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii;
    lines: array [1..maxLines] of linerecp; (* what's on the screen + some *)
    ppLines: array [1..maxPPLines] of linerecp;	(* for page printer *)
    marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
    smartTerminal: boolean; (* true = insert/delete, false = redraw line *)
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
    nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;		(* set by GO *)
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines from elsewhere: }

	(* From ALLOC *)
function newNode: nodep;					external;

	(* From EAUX1B *)
function copyExpr(n: nodep; lcp: boolean): nodep;		external;

	(* From EAUX1C *)
procedure relExpr(n: nodep);					external;
function evalOrder(what,last: nodep; pcons: boolean): nodep;	external;
procedure errprnt;						external;

	(* From PP *)
procedure ppLine; 						external;
procedure ppOutNow; 						external;
procedure ppChar(ch: ascii); 					external;
procedure pp5(ch: c5str; length: integer); 			external;
procedure pp10(ch: cstring; length: integer); 			external;
procedure pp10L(ch: cstring; length: integer);			external;
procedure pp20(ch: c20str; length: integer); 			external;
procedure pp20L(ch: c20str; length: integer); 			external;
procedure ppInt(i: integer); 					external;
procedure ppReal(r: real); 					external;
procedure ppStrng(length: integer; s: strngp); 			external;
procedure ppDtype(d: datatypes);				external;

(* aux routine to set up evaluation order for motions: moveOrder *)

procedure moveOrder(st: statementp); external;
procedure moveOrder;
 var b,byp,movep,operatep,centerp,openp,floatp,arrp,gathering,notaxis,ffp: boolean;
     cl, lexpr, dest, bydest, appr, depr, wobble, sfac, dur, vel, torquecl: nodep;
     load, stiff, ffr, fn1: nodep; useForce, cmForce: integer;

 procedure ffcompare(ff2: nodep);
  var b: boolean; v1,v2: varidefp;
  begin (* ffcompare *)
  if ff2 <> nil then
   if ffr = nil then ffr := ff2		(* remember first force frame we see *)
    else
     begin				(* see if they match *)
     b := ffr↑.csys = ff2↑.csys;	(* make sure they use same coord sys *)
     v1 := nil;
     v2 := nil;
     with ffr↑.ff↑ do
      if ntype = leafnode then
	if ltype = pconstype then v1 := cname
	 else if ltype = varitype then v1 := vari else b := false
       else if (ntype = exprnode) and (op = arefop) then v1 := arg1↑.vari
       else b := false;
     with ff2↑.ff↑ do
      if ntype = leafnode then
	if ltype = pconstype then v2 := cname
	 else if ltype = varitype then v2 := vari else b := false
       else if (ntype = exprnode) and (op = arefop) then v2 := arg1↑.vari
       else b := false;
     if not (b or (v1 = v2)) then
       begin
       pp20L(' MOVE statement has ',20); pp20('multiply defined for',20);
       pp10('ce frames ',9); errPrnt;
       end;
     end;
  end (* ffcompare *);

 procedure fcheck(fn: nodep);			(* check force axis is ok *)
  var vec: vectorp; 

  procedure badvector(fn: nodep);		(* axis error *)
   var bad: nodep;
   begin
   pp20L(' Force direction mus',20); pp20('t be along an axis -',20);
   pp20(' assuming zhat      ',14); errPrnt;
   bad := newNode;
   with bad↑ do
     begin
     ntype := exprnode;
     op := badop;
     arg1 := fn↑.fvec;
     arg2 := newNode;
     end;
   with bad↑.arg2↑ do
     begin ntype := leafnode; ltype := vectype; v := zhat end;
   fn↑.fvec := bad;
   end;

  begin (* fcheck *)	(* note: can't really check variables or expressions *)
  ffcompare(fn↑.fframe);		(* first check its force frame *)
  if (useForce + cmForce > 1) and notaxis then
    begin			(* first force spec was bad - fix it now *)
    pp20L(' In previous force s',20); pp20('pecification:       ',13); errPrnt;
    badvector(fn1);
    end;
  vec := nil;
  with fn↑.fvec↑ do
   if ntype = leafnode then vec := pcval↑.v	(* first check if axis vector *)
   else if op = vnegop then 			(* or negative axis vector *)
    if arg1↑.ntype = leafnode then vec := arg1↑.pcval↑.v;
  if not((vec = xhat) or (vec = yhat) or (vec = zhat)) then
   if useForce + cmForce = 1 then
     begin					(* single sense/apply *)
     fn1 := fn;
     notaxis := true;		(* remember that it's not along an axis *)
     end
    else badvector(fn);				(* multiple axes - error *)
  end (* fcheck *);

 begin (* moveOrder *)
 arrp := false;
 byp := false;
 dest := nil;
 bydest := nil;
 appr := nil;
 depr := nil;
 wobble := nil;
 sfac := nil;
 dur := nil;
 load := nil;
 useForce := 0;
 cmForce := 0;
 stiff := nil;
 gathering := false;
 ffp := false;
 ffr := nil;
 fn1 := nil;
 notaxis := false;
 movep := false;
 operatep := false;
 centerp := false;
 floatp := false;
 openp := false;
 with st↑ do
  if (stype = movetype) or (stype = jtmovetype) then movep := true
   else if stype = operatetype then operatep := true
   else if stype = centertype then centerp := true
   else if stype = floattype then floatp := true else openp := true;
 cl := st↑.clauses;
 if cl <> nil then
   with cl↑ do
    if (ntype = ffnode) and pdef then
      begin				(* flush any system created fframes *)
      st↑.clauses := cl↑.next;		(* though we may recreate it below *)
      relExpr(cl);
      cl := st↑.clauses;
      end;
 while cl <> nil do			(* run through the clauses *)
  with cl↑ do
   begin
   case ntype of
destnode:	begin
		if dest <> nil then
		 begin
		 pp20L(' Can only specify on',20); pp20('e destination for a ',20);
		 pp10('motion!   ',7); errPrnt;
		 end;
		dest := cl;
		end;
apprnode:	if loc <> nil then begin appr := cl; byp := false end;
deprnode:	if loc <> nil then depr := cl;
viaptnode:	byp := false;
byptnode:	begin byp := true; bydest := cl end;
gathernode:	gathering := true;
stiffnode:	begin stiff := cl; ffcompare(cocff) end;
wobblenode:	wobble := cl;
sfacnode:	sfac := cl;
durnode:	dur := cl;
loadnode:	load := cl;
ffnode:		begin
		ffcompare(cl);
		if not ffp then begin ffr := cl; ffp := true end;
		end;
forcenode:	begin
		useForce := useForce + 1;
		if movep then fcheck(cl);
		end;
cmonnode:	with cl↑.cmon↑.oncond↑ do
		 if ntype = forcenode then
		   begin
		   cmForce := cmForce + 1;
		   if movep then fcheck(cl↑.cmon↑.oncond);
		   end
		  else if ntype = arrivalnode then
		   begin
		   if arrp then
		     begin
		     pp20L(' Can only specify on',20); pp20('e "ON ARRIVAL DO" fo',20);
		     pp20('r a motion!         ',11); errPrnt;
		     end;
		   arrp := true;
		   end;
otherwise 	{do nothing};
    end;
   cl := next;
   end;

 if (dest = nil) and (not byp) and (appr = nil) then
   begin
   if movep then
    begin
    pp20L(' Need destination fo',20); pp20('r motion statement! ',19); errPrnt;
    end
   end;

 if notaxis and (useForce + cmForce = 1) then
   begin					(* single sense/apply *)
   b := ffr = nil;
   if not b then
    if not ffr↑.pdef then
     begin
     pp20L(' Can''t specify a for',20); pp20('ce frame with a rand',20);
     pp20('om force vector     ',15); errPrnt;
     b := true;
     end;
   if b then
     begin
     ffr := newNode;			(* make up a new force frame *)
     with ffr↑ do
      begin
      next := st↑.clauses;
      ntype := ffnode;
      ff := newNode;
      with ff↑ do
       begin
       ntype := exprnode;
       op := vmkfrcop;		(* need to compute force frame *)
       arg1 := copyExpr(fn1↑.fvec,true);
       arg2 := nil;
       arg3 := nil;
       end;
      csys := true;		(* use world coords *)
      pdef := true;
      end;
     st↑.clauses := ffr;
     end;
   end
  else if (ffr <> nil) and not ffp then
   begin			(* need to add force frame specification *)
   cl := ffr;			(* force frame from force or stiffness node *)
   ffr := newNode;		(* make up a new force frame *)
   with ffr↑ do
    begin
    next := st↑.clauses;
    ntype := ffnode;
    ff := copyExpr(cl↑.ff,true);
    csys := true;		(* use world coords *)
    pdef := true;
    end;
   st↑.clauses := ffr;
   end;

(* now set up those expressions that need to be evaluated for this motion *)

 lexpr := nil;
 with st↑ do
  if cf <> nil then				(* evaluate control frame *)
   if cf↑.ntype <> leafnode then
     if cf↑.op = arefop then
       lexpr := evalOrder(cf↑.arg2,nil,true)	(* push array subscripts *)
      else lexpr := evalOrder(cf↑.arg2↑.lval,nil,true);	(* only 1 sub for jointop *)

 if not floatp then
   begin
   if (sfac <> nil) and ((dest <> nil) or (bydest <> nil)) then	(* evaluate speed factor *)
    lexpr := evalOrder(sfac↑.clval,lexpr,false);
   if dur <> nil then			(* evaluate global time duration *)
    lexpr := evalOrder(dur↑.durval,lexpr,false);
   end;

 if movep then
   if wobble <> nil then			(* evaluate wobble *)
    lexpr := evalOrder(wobble↑.clval,lexpr,false);

 if (movep or floatp) and (load <> nil) then	(* evaluate load *)
   begin
   lexpr := evalOrder(load↑.loadval,lexpr,false);
   lexpr := evalOrder(load↑.loadvec,lexpr,false);
   end;

 if movep then
   begin				(* MOVE statement has extra clauses *)
   if ffr <> nil then				(* evaluate force frame *)
    lexpr := evalOrder(ffr↑.ff,lexpr,false);
   if stiff <> nil then				(* deal with stiffness *)
    begin
    lexpr := evalOrder(stiff↑.fv,lexpr,false);	(* evaluate force vector *)
    lexpr := evalOrder(stiff↑.mv,lexpr,false);	(* evaluate torque vector *)
    end;
   cl := st↑.clauses;
   while cl <> nil do				(* run through clauses *)
    begin
    if cl↑.ntype = forcenode then		(* evaluate bias force values *)
     lexpr := evalOrder(cl↑.fval,lexpr,false);
    cl := cl↑.next;
    end;
   if depr <> nil then				(* evaluate departure *)
    lexpr := evalOrder(depr,lexpr,false);
   cl := st↑.clauses;
   while cl <> nil do				(* run through clauses *)
    begin
    if (cl↑.ntype = viaptnode) or (cl↑.ntype = byptnode) then
     lexpr := evalOrder(cl,lexpr,false);	(* evaluate via & by points *)
    cl := cl↑.next;
    end;
   if appr <> nil then				(* evaluate approach *)
    lexpr := evalOrder(appr,lexpr,false);
   end
  else if operatep then
   begin					(* handle OPERATE *)
   torquecl := nil;
   vel := nil;
   cl := st↑.clauses;
   while cl <> nil do				(* run through clauses *)
    with cl↑ do
     begin
     if ntype = forcenode then
       if ftype = torque then torquecl := cl
	else if ftype = angvelocity then vel := cl;
     cl := next;
     end;
   if vel <> nil then 				(* evaluate angular velocity *)
    lexpr := evalOrder(vel↑.fval,lexpr,false);
   if torquecl <> nil then 				(* evaluate torque *)
    lexpr := evalOrder(torquecl↑.fval,lexpr,false);
   end
  else if openp then
   begin					(* handle OPEN/CLOSE *)
   cl := st↑.clauses;
   while cl <> nil do				(* run through clauses *)
    begin
    if cl↑.ntype = swtnode then	(* evaluate stop wait time for vise *)
      begin
      lexpr := evalOrder(cl↑.clval,lexpr,false);
      cl := nil;
      end
     else cl := cl↑.next;
    end;
   if (dest = nil) and (bydest <> nil) then	(* evaluate BY = dest *)
     lexpr := evalOrder(bydest,lexpr,false);
   end;

 if (not (centerp or floatp)) and (dest <> nil) then (* evaluate destination *)
  lexpr := evalOrder(dest,lexpr,false);

 if not floatp then
   begin
   cl := st↑.clauses;
   while cl <> nil do				(* run through clauses *)
    with cl↑ do
     begin
     if (ntype = cmonnode) and errHandlerp then	(* evaluate error conds *)
       lexpr := evalOrder(cmon↑.oncond↑.eexpr,lexpr,false);
     cl := next;
     end;
   end;

 st↑.exprs := lexpr;
 end (* moveOrder *);