COMMENT ⊗   VALID 00004 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	Editor: debugging routines }
C00031 00003	{ Externally defined routines from elsewhere: }
C00035 00004	(* debugging routines: dGetPdb,dfreePdb,getPCline,runStmnt,executeStmnt,pevalExpr,goStmnt *)
C00049 ENDMK
C⊗;
{$NOMAIN	Editor: debugging routines }

(* definition of record types & global variables used by AL *)

const 

  maxLines = 28;
  maxPPLines = 12;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

type

(* random type declarations for OMSI/SAIL compatibility *)

 ascii = char;
 atext = text;
 byte = 0..255;	

(* Here are all the pointer-type definitions.  Since the various 	*)
(* records reference each other so much, we have to put them all here.	*)

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
identp = ↑ident;
tokenp = ↑token;
reswordp = ↑resword;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑message;
linerecp = ↑linerec;


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;
vector = record  refcnt: integer; val: array [1..3] of real end;
trans = record  refcnt: integer; val: array [1..3,1..4] of real end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;


(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    progtype:	    (pcode: statementp; errors: integer);
    blocktype,
    declaretype,
    endtype,
    coendtype:	    (bcode, bparent: statementp; blkid: identp;
			level, numvars: 0..255; variables: varidefp);
    coblocktype:    (threads: nodep; nthreads: integer; cblkid: identp);
    prompttype,
    printtype,
    aborttype,
    saytype:	    (plist: nodep; debugLev: integer);
    assigntype:     (what, aval: nodep);
    cmtype:	    (oncond: nodep; conclusion: statementp;
			deferCm, exprCm: boolean; cdef: varidefp);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: tokenp);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: identp);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    listnode:	(lval: nodep);
    clistnode:	(cval: integer; stmnt: statementp; clast: nodep);
    colistnode:	(prev: nodep; cstmnt: statementp);
    cmonnode:	(cmon: statementp; errhandlerp: boolean);
    waitlistnode: (who: pdbp; when: integer);
    procdefnode:(ptype: datatypes; level: 0..255;
		    pname, paramlist: varidefp; body: statementp);
	end;



(* records for parser: ident, token, resword *)

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;


tokentypes = (reswdtype, identtype, constype, comnttype, delimtype, labeldeftype,
		macpartype);

constypes = svaltype..strngtype;

reswdtypes = (stmnttype, filtype, clsetype, decltype, optype, edittype);

filtypes = (abouttype,alongtype,attype,bytype,defertype,dotype,elsetype,
		errmodestype,fromtype,handtype,intype,nonrigidlytype,rigidlytype,
		sourcefiletype,steptype,thentype,totype,untltype,viatype,
		withtype,worldtype,zeroedtype,oftype,wheretype,nowaittype,
		ontype,offtype,ppsizetype,collecttype,alltype,lextype,
		notype,righttype,lefttype,uptype,downtype,motiontype);

clsetypes = (approachtype,arrivaltype,departuretype,departingtype,durationtype,
		errortype,forcetype,forceframetype,forcewristtype,gathertype,
		nildeproachtype,nullingtype,stiffnesstype,
		torquetype,velocitytype,wobbletype,
		cwtype,ccwtype,stopwaittimetype,angularvelocitytype,
		respecttype,elbowtype,shouldertype,fliptype,lineartype,
		jointspacetype,loadtype);

edittypes = (getcmd,savecmd,insertcmd,renamecmd,startcmd,gocmd,proceedcmd,
		stepcmd,sstepcmd,nstepcmd,gstepcmd,executecmd,setcmd,tracecmd,
		breakcmd,unbreakcmd,tbreakcmd,definecmd,markcmd,unmarkcmd,
		popcmd,atcmd,calibratecmd);

token = record
	  next: tokenp;
	  case ttype: tokentypes of
constype:   (cons: nodep);
comnttype:  (len: integer; str: strngp);
delimtype:  (ch: ascii);
reswdtype:  (case rtype: reswdtypes of
	stmnttype: (stmnt: stmntypes);
	filtype:   (filler: filtypes);
	clsetype:  (clause: clsetypes);
	decltype:  (decl: datatypes);
	optype:	   (op: exprtypes);
	edittype:  (ed: edittypes) );
identtype:  (id: identp);
labeldeftype: (lab: varidefp);
macpartype: (mpar: varidefp);
	end;


resword = record
	  next: reswordp;
	  length: integer;
	  name: strngp;
	  case rtype: reswdtypes of
	stmnttype:  (stmnt: stmntypes);
	filtype:    (filler: filtypes);
	clsetype:   (clause: clsetypes);
	decltype:   (decl: datatypes);
	optype:	    (op: exprtypes);
	edittype:  (ed: edittypes);
	  end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* definition of AL-ARM messages *)

msgtypes = (initarmscmd,calibcmd,killarmscmd,wherecmd,
	    abortcmd,stopcmd,movehdrcmd,movesegcmd,
	    centercmd,operatecmd,movedonecmd,signalcmd,
	    setccmd,forcesigcmd,forceoffcmd,biasoncmd,biasoffcmd,setstiffcmd,
	    zerowristcmd,wristcmd,gathercmd,getgathercmd,readadccmd,writedaccmd,
	    errorcmd,floatcmd,setloadcmd,
	    armmagiccmd,realcmd,vectorcmd,transcmd);

errortypes = (noerror,noarmsol,timerr,durerr,toolong,featna,
	      unkmess,srvdead,adcdead,nozind,exjtfc,paslim,nopower,badpot,devbusy,
	      baddev,timout,panicb,nocart,cbound,badparm);

message = record
	   cmd: msgtypes;
	   ok: boolean;
	   case integer of
	1:   (dev, bits, n: integer;
(*	     (dev, bits, n, evt: integer;	(* for arm code version *)
	      evt: eventp;
	      dur: real;
	      case integer of
		1: (v1,v2,v3: real);
		2: (sfac,wobble,pos: real);
		3: (val,angle,mag: real);
		4: (max,min: real);
		5: (error: errortypes));
	2:   (fv1,fv2,fv3,mv1,mv2,mv3: real);	(* may never use these... *)
	3:   (t: array [1..6] of real);
	  end;

interr = record
         case integer of
           0: (i: integer);
	   1: (err,foo: errortypes);
	 end;



(* print related records: *)

cursorp = record
	  cline,ind: integer;
	  case stmntp: boolean of
  true:    (st: statementp);
  false:   (nd: nodep);
	 end;

linerec = record
	next: linerecp;
	start,length: integer
       end;

listingarray = packed array [0..listinglength] of ascii;



(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
    lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii;
    lines: array [1..maxLines] of linerecp; (* what's on the screen + some *)
    ppLines: array [1..maxPPLines] of linerecp;	(* for page printer *)
    marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
    smartTerminal: boolean; (* true = insert/delete, false = redraw line *)
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
    nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;		(* set by GO *)
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines from elsewhere: }

	(* From ALLOC *)
function newNode: nodep;					external;
function newStatement: statementp;				external;
function newPdb: pdbp;						external;
procedure relPdb(n: pdbp);					external;

	(* From FREE *)
procedure freeNode(n: nodep);					external;
procedure freeStatement(s: statementp);				external;

	(* From CALLER:  Inter-overlay calls *)
procedure edbInterp(dLev,which: integer);			external;
procedure edbFlLevel(dLev: integer);				external;
procedure edbUnwind(p: pdbp; eLev: integer);			external;
procedure edbFlKids(p: pdbp; zapit: boolean);			external;

	(* From IAUX1A *)
function getELev(hdr: envheaderp): integer;			external;

	(* From IAUX1B *)
procedure swap(newp: pdbp);					external;

	(* From EAUX1A *)
procedure adjustDisplay;					external;

	(* From EAUX1C *)
function evalOrder(what,last: nodep; pcons: boolean): nodep;	external;

	(* From EAUX2C *)
procedure setECurInt;						external;
procedure displayLines(var pfrom: integer);			external;

	(* From ETOKEN *)
procedure getToken;						external;

	(* From EPUTST *)
procedure putstmnt(s: statementp; indent, plevel: integer);	external;

	(* From PP *)
procedure ppLine; 						external;
procedure ppOutNow; 						external;
procedure ppChar(ch: ascii); 					external;
procedure pp5(ch: c5str; length: integer); 			external;
procedure pp10(ch: cstring; length: integer); 			external;
procedure pp10L(ch: cstring; length: integer);			external;
procedure pp20(ch: c20str; length: integer); 			external;
procedure pp20L(ch: c20str; length: integer); 			external;
procedure ppInt(i: integer); 					external;
procedure ppReal(r: real); 					external;
procedure ppStrng(length: integer; s: strngp); 			external;

	(* From EROOT *)
function edbExprParse: nodep;					external;
function edbAddNewDeclarations: integer;			external;

procedure eDbgGet; external;
procedure eDbgGet;  begin end;

(* debugging routines: dGetPdb,dfreePdb,getPCline,runStmnt,executeStmnt,pevalExpr,goStmnt *)

function dGetPdb(st: statementp): pdbp; external;
function dGetPdb;
 var p: pdbp;
 begin
 p := newPdb;
 with p↑ do
  begin				(* initialize it somewhat *)
  nextPdb := debugPdbs[debugLevel];
  debugPdbs[debugLevel] := p;	(* add us to list of all debugger processes *)
  next := nil;
  env := eCurInt↑.env;
  level := getELev(env) + 1;
  priority := 10 * debugLevel;	(* use priority level for debug level *)
  cm := eCurInt↑.cm;
  mech := eCurInt↑.mech;
  status := nullqueue;
  mode := 0;
  spc := st;
  epc := nil;
  sp := nil;
  procp := false;
  if eCurInt↑.procp then opdb := eCurInt else opdb := nil;	(* for RETURN *)
  sdef := st;			(* so we can easily release it later *)
  linenum := 0;
  end;
 dGetPdb := p;
 end;

procedure dfreePdb(p: pdbp); external;
procedure dfreePdb;
 var po: pdbp; b: boolean;
 begin					(* remove pdb from list *)
 if debugPdbs[debugLevel] = p then debugPdbs[debugLevel] := p↑.nextPdb
  else
   begin
   po := debugPdbs[debugLevel];
   b := false;
   repeat				(* find pdb in list *)
    if po↑.nextPdb = p then b := true else po := po↑.nextPdb
   until b or (po = nil);
   if b then po↑.nextPdb := p↑.nextPdb;	(* splice us out of list *)
(* *** else complain??? *** *)
   end;
 with p↑ do
  if (spc↑.stype = aborttype) and (spc↑.debugLev >= debugLevel) then
    begin
    with spc↑ do
     if spc↑.last↑.last = nil then freeStatement(spc↑.last) (* can flush it *)
      else
       begin
       last↑.next := next;		(* splice abort out now *)
       next↑.last := last;
       end;
    freeStatement(spc);
    end;
 relPdb(p);
 end;

function getPCline(st: statementp): integer; external;
function getPCline;
 begin
 if st = nil then getPCline := 1
  else if st↑.stype = progtype then getPCline := 1
  else
   begin
   findStmnt := st;
   setCursor := false;
   curLine := 0;
   firstLine := 0;
   lastLine := -1;
   if debuglevel = 0 then findLine := 1 else findLine := 0;
   putStmnt(dprog,0,99);		(* find line cursor is on *)
   getPCline := findLine;
   end;
 end;

 procedure runStmnt(which: integer); external;
 procedure runStmnt;
  (* WHICH tells us which of the MAINn overlays called us *)
  var p: pdbp; b,bp: boolean; st: statementp; i: integer;

    procedure clrTBpts;             (* Copied from EAUX3B *)
     var i: integer;
     begin
     for i := 1 to ntbpts do
      begin tbpts[i]↑.bpt := false; tbpts[i] := nil end;
     ntbpts := 0;
     end;

  begin
  edbFlLevel(debugLevel+1);		(* Get rid of any previous garbage *)
  edbInterp(debugLevel,which);			(* Go interpret it *)
  if ppBufp > 0 then ppLine;
  bp := true;
  p := curInt;
  if p <> nil then
    with p↑ do
     if (debugLevel > 0) and (priority >= 10 * debugLevel) and (spc <> nil) then
       if (spc↑.stype = aborttype) and (spc↑.debugLev >= debugLevel) then
	 begin				(* immediate executed stmnt *)
	 dfreePdb(p);
	 swap(nil);			(* swap in next active process *)
	 p := curInt;		(* & see what we've got *)
	 bp := false;
	 end;
  b := true;
  while (debugLevel > 0) and b do
   if debugPdbs[debugLevel] = nil then debugLevel := debugLevel - 1
    else b := false;
  if (debugLevel < STLevel) and tSingleThreadMode then
    begin
    STLevel := 0;
    tSingleThreadMode := false;
    if not singleThreadMode then iSingleThreadMode := false;
    end;
  if debugLevel > 0 then
    begin pp10('Level:    ',7); ppInt(debugLevel); ppChar('.') end;
  if p <> nil then
    begin
    st := p↑.spc;
    eCurInt := p;			(* remember current context *)
    end
   else
    begin
(* Must have been an escape-I abort with all processes currently swapped out *)
    if bp then				(* only complain first time through *)
      begin pp20('No processes current',20); pp10('ly active.',10); ppLine end;
    st := dprog↑.pcode;		(* stick us at beginning *)
    eCurInt := debugPdbs[0];	(* and use outermost level for now *)
    eCurInt↑.linenum := 2;
    end;
  if not bp then pcLine := eCurInt↑.linenum;
  if st↑.bpt then
    begin
    b := true;
    if st↑.stype = endtype then
      if bp and (st↑.bparent = dprog↑.pcode) then
	begin
	pp10('All Done  ',9);
	b := false;
	p↑.spc := dprog↑.pcode↑.bcode;	(* proceed will take it from the top *)
	end;
    if b and bp then
      begin pp10('BPT       ',4); ppOutNow end;	(* say we've hit a bpt *)
    end
   else if st↑.bad then
    begin pp20('Attempt to execute B',20); pp20('AD statement!       ',13);
	  ppLine;			(* complain *)
    end;
  clrTBpts;				(* clear any temporary bpts *)
  if bp then
    begin
    i := getPCline(st);
    if i > 0 then
      begin
      pcLine := i;
      setCursor := true;
      cursorLine := pcLine;
      adjustDisplay;
      displayLines(lineNum);		(* shift display if necessary *)
      end;
    end;
  for i := 1 to 2 do
   begin
   if i = 1 then p := allPdbs
    else if debugLevel > 0 then p := debugPdbs[debugLevel] else p := nil;
   while p <> nil do		(* run through all the active processes *)
    with p↑ do			(* & see where they are now *)
     begin
     if priority >= 10 * debuglevel then linenum := getPCline(spc);
     p := nextPdb;
     end;
   end;
  end;

procedure executeStmnt(st: statementp; which: integer); external;
procedure executeStmnt;
 (* "which" tells us which of the MAINn overlays called us *)
 var p: pdbp; sp: statementp;
 begin
 debugLevel := debugLevel + 1;		(* move us to a new debugging level *)
 p := dGetPdb(st);	(* get a new process with same environment as curInt *)
 sp := newStatement;
 with sp↑ do
  begin
  stype := aborttype;
  debugLev := debugLevel;
  plist := nil;
  nlines := 0;
  last := st;
  next := st↑.next;
  end;
 st↑.next := sp;		(* splice in pseudo-abort stmnt *)
 if sp↑.next <> nil then sp↑.next↑.last := sp;
 swap(p);			(* swap us in *)
 runStmnt(which);		(* have interpreter do it *)
 setECurInt;
 end;

procedure pevalExpr(n: nodep; which: integer); external;
procedure pevalExpr;
 (* "which" tells us which of the MAINn overlays called us *)
 var peval: statementp; b: boolean; np,no: nodep; i: integer;
 begin
 if n <> nil then
   begin
   peval := newStatement;
   with peval↑ do
    begin
    if (n↑.ntype = exprnode) and (n↑.op = callop) then
      b := n↑.arg1↑.vari↑.vtype = nulltype else b := false;
    if b then
      begin
      stype := calltype;
      what := n;
      end
     else if (n↑.ntype = exprnode) and (n↑.op = dacop) then
      begin
      stype := assigntype;
      what := n;
      end
     else
      begin
      stype := printtype;
      plist := newNode;
      with peval↑.plist↑ do
       begin ntype := listnode; next := nil; lval := n end;
      n := plist;
      no := n;
      with curToken do
       while (ttype = delimtype) and (ch = ',') do
	begin
	np := newNode;
	with np↑ do
	 begin ntype := listnode; next := nil; lval := edbExprParse end;
	if np↑.lval = nil then freeNode(np)
	 else
	  begin
	  no↑.next := np;	(* add a new expression to the list *)
	  no := np;
	  end;	
	getToken;		(* look for "," *)
	end;
      end;
    exprs := evalOrder(n,nil,false);
    i := edbAddNewDeclarations;
    executeStmnt(peval,which);	(* have interpreter eval & print it out *)
    end;
   end;
 end;

procedure goStmnt(which: integer); external;
procedure goStmnt;
 (* "which" tells us which of the MAINn overlays called us *)
var i,j: integer; b: boolean;
begin
(* *** should do more checking so we don't get in big trouble, but.... *** *)
(* *** like jumping into a procedure body, etc. *** *)
 i := cursor;
 b := false;
 repeat
  with cursorStack[i] do
   if stmntp then b := st↑.stype = blocktype;
   if not b then i := i - 1;
 until b or (i = 0);
 if b then
   begin				(* unwind any inner blocks *)
   j := cursorStack[i].st↑.level;
   if getELev(eCurInt↑.env) > j then edbUnwind(eCurInt,j);
   end;
 edbFlKids(eCurInt,false);	(* flush any processes we had sprouted *)
 if not tSingleThreadMode then
   begin			(* see if within a cobegin thread *)
   for i := 3 to cursor do
    with cursorStack[i] do
     if not stmntp then
       if nd↑.ntype = colistnode then tSingleThreadMode := true;
   if tSingleThreadMode then
     if eCurInt↑.procp or (eCurInt↑.evt = nil) then
       begin		(* not currently in an active thread *)
       STLevel := eCurInt↑.priority div 10;
       iSingleThreadMode := true;
       end
      else tSingleThreadMode := false;
   end;
 with eCurInt↑ do
  begin
  spc := cursorStack[cursor].st;
  mode := 0;
  epc := nil;
  debugLevel := priority div 10;	(* pop up to our level (oh???) *)
  end;
 swap(eCurInt);
 runStmnt(which);			(* Go from where ever we are *)
 end;