perm filename EAUX3A.2[EAL,HE] blob sn#708955 filedate 1983-05-01 generic text, type C, neo UTF8
COMMENT ⊗   VALID 00010 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	Editor: Plain old aux routines mostly called by Edit }
C00031 00003	{ Externally defined routines from elsewhere: }
C00035 00004	(* aux routines: setPPSize, flushOldEnvironments, saveOutermostEnv *)
C00048 00005	(* initOuterBlock *)
C00050 00006	(* Aux routine: setUpStmnt *)
C00052 00007	(* makeOuterBlock *)
C00053 00008	(* aux routines: fileParse, writeProg, readProg *)
C00060 00009	(* Aux routines called by edit: getEcmd, doSetCmd *)
C00066 00010	(* Stupid little procedure to open the talking box: openTalk *)
C00068 ENDMK
C⊗;
{$NOMAIN	Editor: Plain old aux routines mostly called by Edit }

(* definition of record types & global variables used by AL *)

const 

  maxLines = 28;
  maxPPLines = 18;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

type

(* random type declarations for OMSI/SAIL compatibility *)

 ascii = char;
 atext = text;
 byte = 0..255;	

(* Here are all the pointer-type definitions.  Since the various 	*)
(* records reference each other so much, we have to put them all here.	*)

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
identp = ↑ident;
tokenp = ↑token;
reswordp = ↑resword;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑message;
linerecp = ↑linerec;


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;
vector = record  refcnt: integer; val: array [1..3] of real end;
trans = record  refcnt: integer; val: array [1..3,1..4] of real end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;


(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    progtype:	    (pcode: statementp; errors: integer);
    blocktype,
    declaretype,
    endtype,
    coendtype:	    (bcode, bparent: statementp; blkid: identp;
			level, numvars: 0..255; variables: varidefp);
    coblocktype:    (threads: nodep; nthreads: integer; cblkid: identp);
    saytype:	    (plist: nodep; debugLev: integer);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: tokenp);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: identp);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    listnode:	(lval: nodep);
    clistnode:	(cval: integer; stmnt: statementp; clast: nodep);
    colistnode:	(prev: nodep; cstmnt: statementp);
	end;



(* records for parser: ident, token, resword *)

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;


tokentypes = (reswdtype, identtype, constype, comnttype, delimtype, labeldeftype,
		macpartype);

constypes = svaltype..strngtype;

reswdtypes = (stmnttype, filtype, clsetype, decltype, optype, edittype);

filtypes = (abouttype,alongtype,attype,bytype,defertype,dotype,elsetype,
		errmodestype,fromtype,handtype,intype,nonrigidlytype,rigidlytype,
		sourcefiletype,steptype,thentype,totype,untltype,viatype,
		withtype,worldtype,zeroedtype,oftype,wheretype,nowaittype,
		ontype,offtype,ppsizetype,collecttype,alltype,lextype,
		notype,righttype,lefttype,uptype,downtype,motiontype);

clsetypes = (approachtype,arrivaltype,departuretype,departingtype,durationtype,
		errortype,forcetype,forceframetype,forcewristtype,gathertype,
		nildeproachtype,nullingtype,stiffnesstype,
		torquetype,velocitytype,wobbletype,
		cwtype,ccwtype,stopwaittimetype,angularvelocitytype,
		respecttype,elbowtype,shouldertype,fliptype,lineartype,
		jointspacetype,loadtype);

edittypes = (getcmd,savecmd,insertcmd,renamecmd,startcmd,gocmd,proceedcmd,
		stepcmd,sstepcmd,nstepcmd,gstepcmd,executecmd,setcmd,tracecmd,
		breakcmd,unbreakcmd,tbreakcmd,definecmd,markcmd,unmarkcmd,
		popcmd,atcmd,calibratecmd);

token = record
	  next: tokenp;
	  case ttype: tokentypes of
constype:   (cons: nodep);
comnttype:  (len: integer; str: strngp);
delimtype:  (ch: ascii);
reswdtype:  (case rtype: reswdtypes of
	stmnttype: (stmnt: stmntypes);
	filtype:   (filler: filtypes);
	clsetype:  (clause: clsetypes);
	decltype:  (decl: datatypes);
	optype:	   (op: exprtypes);
	edittype:  (ed: edittypes) );
identtype:  (id: identp);
labeldeftype: (lab: varidefp);
macpartype: (mpar: varidefp);
	end;


resword = record
	  next: reswordp;
	  length: integer;
	  name: strngp;
	  case rtype: reswdtypes of
	stmnttype:  (stmnt: stmntypes);
	filtype:    (filler: filtypes);
	clsetype:   (clause: clsetypes);
	decltype:   (decl: datatypes);
	optype:	    (op: exprtypes);
	edittype:  (ed: edittypes);
	  end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* definition of AL-ARM messages *)

msgtypes = (initarmscmd,calibcmd,killarmscmd,wherecmd,
	    abortcmd,stopcmd,movehdrcmd,movesegcmd,
	    centercmd,operatecmd,movedonecmd,signalcmd,
	    setccmd,forcesigcmd,forceoffcmd,biasoncmd,biasoffcmd,setstiffcmd,
	    zerowristcmd,wristcmd,gathercmd,getgathercmd,readadccmd,writedaccmd,
	    errorcmd,floatcmd,setloadcmd,
	    armmagiccmd,realcmd,vectorcmd,transcmd);

errortypes = (noerror,noarmsol,timerr,durerr,toolong,featna,
	      unkmess,srvdead,adcdead,nozind,exjtfc,paslim,nopower,badpot,devbusy,
	      baddev,timout,panicb,nocart,cbound,badparm);

message = record
	   cmd: msgtypes;
	   ok: boolean;
	   case integer of
	1:   (dev, bits, n: integer;
(*	     (dev, bits, n, evt: integer;	(* for arm code version *)
	      evt: eventp;
	      dur: real;
	      case integer of
		1: (v1,v2,v3: real);
		2: (sfac,wobble,pos: real);
		3: (val,angle,mag: real);
		4: (max,min: real);
		5: (error: errortypes));
	2:   (fv1,fv2,fv3,mv1,mv2,mv3: real);	(* may never use these... *)
	3:   (t: array [1..6] of real);
	  end;

interr = record
         case integer of
           0: (i: integer);
	   1: (err,foo: errortypes);
	 end;



(* print related records: *)

cursorp = record
	  cline,ind: integer;
	  case stmntp: boolean of
  true:    (st: statementp);
  false:   (nd: nodep);
	 end;

linerec = record
	next: linerecp;
	start,length: integer
       end;

listingarray = packed array [0..listinglength] of ascii;



(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
    lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii;
    lines: array [1..maxLines] of linerecp; (* what's on the screen + some *)
    ppLines: array [1..maxPPLines] of linerecp;	(* for page printer *)
    marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
    smartTerminal: boolean; (* true = insert/delete, false = redraw line *)
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
    nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;		(* set by GO *)
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines from elsewhere: }

	(* From ALLOC *)
function newStatement: statementp;				external;
function newEheader: envheaderp; 				external;

	(* From CALLER *)
procedure e3aFlushAll(p: pdbp; dLev: integer);			external;
procedure e3aInterp(dLev: integer);				external;

	(* From FREE *)
procedure freeStatement(s: statementp);				external;

	(* From IAUX1B *)
procedure swap(newp: pdbp);					external;

	(* From EAUX1A *)
procedure out1Line(line,start,length: integer); 		external;
procedure clearLine(i: integer);				external;
function upperCase(c: ascii): ascii;				external;
procedure borderLines;						external;
procedure adjustDisplay;					external;

	(* From EAUX1B *)
procedure appendEnd(s,so: statementp);				external;

	(* From EAUX1C *)
procedure relExpr(n: nodep);					external;

	(* From EEXPED *)
function exprEditor(line,lstart,llength,estart: integer;
	var elength: integer; off: integer): ascii;		external;

	(* From ETOKEN *)
procedure getToken;						external;

	(* From EAUX2C *)
procedure displayLines(var pfrom: integer);			external;

	(* From EAUX2D *)
procedure readline;						external;

	(* From EPUTST *)
procedure putstmnt(s: statementp; indent, plevel: integer);	external;

	(* From PP *)
procedure relLine(l: linerecp);					external;
procedure ppLine; 						external;
procedure ppOutNow; 						external;
procedure ppChar(ch: ascii); 					external;
procedure pp5(ch: c5str; length: integer); 			external;
procedure pp10(ch: cstring; length: integer); 			external;
procedure pp10L(ch: cstring; length: integer);			external;
procedure pp20(ch: c20str; length: integer); 			external;
procedure pp20L(ch: c20str; length: integer); 			external;
procedure ppInt(i: integer); 					external;

	(* From DISP *)
procedure outLine(line,col,start,length: integer); 		external;

procedure eAux3aGet; external;
procedure eAux3aGet;  begin end;

(* aux routines: setPPSize, flushOldEnvironments, saveOutermostEnv *)

procedure setPPSize(arg: integer); external;
procedure setPPSize;
 var delta,i,j,top,bot: integer;
 begin				(* set page printer size to arg *)
 if arg < 3 then arg := 3	(* make sure it's a reasonable request *)
  else if arg > screenHeight - 5 then arg := screenHeight - 5;
 if arg > maxPPlines then arg := maxPPlines;
 delta := arg - ppSize;
 if delta > 0 then
   begin				(* increase page printer size *)
   ppOffset := ppOffset + delta;
   dispHeight := dispHeight - delta;
   adjustDisplay;			(* make sure cursor stays on screen *)
   displayLines(lineNum);		(* shift display if necessary *)
   for i := ppSize downto 1 do ppLines[i+delta] := ppLines[i];
   for i := 1 to delta do 
    begin
    ppLines[i] := nil;			(* we'll roll up later *)
    clearLine(dispHeight + 1 + i);
    end;
   end
  else if delta < 0 then
   begin				(* decrease page printer size *)
   delta := - delta;
   ppOffset := arg;
   for i := 1 to delta do relLine(ppLines[i]);
   for i := 1 to arg do ppLines[i] := ppLines[delta + i];
   for i := arg + 1 to ppSize do ppLines[i] := nil;
   for i := 1 to delta do clearLine(dispHeight + 1 + i);
   top := topDline + firstDline + dispHeight - 1;  (* top line being added *)
   bot := top + delta - 1;			(* last line to add *)
   if bot <= botDline then j := bot else j := botDline;
   for i := top to j do			(* show lines already in display *)
    with lines[i-topDline+1]↑ do
     out1Line(i-topDline-firstDline+2,start,length);
   dispHeight := dispHeight + delta;
   if j < bot then displayLines(lineNum)	(* add new lines *)
    else borderLines;
   end;
 ppSize := arg;
 end;

procedure flushOldEnvironments(dLev: integer); external;
procedure flushOldEnvironments;
 var i: integer; p: pdbp;
 begin			(* tell INTERP to flush old program environment *)
 for i := debugLevel downto dLev do
  begin
  if i > 0 then
    begin
    p := debugPdbs[i];
    while p <> nil do
     with p↑ do
      begin
      if sdef↑.last = nil then 		(* free immediate stmnt & it's abort *)
	begin freeStatement(sdef↑.next); freeStatement(sdef) end
       else
	with sdef↑.next↑ do
	 if (stype = aborttype) and (debugLev >= i) then
	   begin
	   last↑.next := next;
	   next↑.last := last;
	   freeStatement(sdef↑.next);		(* flush pseudo-abort *)
	   end;
      p := next;
      end;
    e3aFlushAll(debugPdbs[i],i);
    debugPdbs[i] := nil;
    end 
   else e3aFlushAll(nil,0);
  end;
 if tSingleThreadMode and (STLevel >= dLev) then
   begin
   STLevel := 0;
   tSingleThreadMode := false;
   if not singleThreadMode then iSingleThreadMode := false;
   end;
 if dLev > 0 then debugLevel := dlev - 1 else debugLevel := 0;
 if curInt = nil then swap(nil);	(* see if anyone's active *)
 eCurInt := curInt;
 if eCurInt <> nil then pcLine := eCurInt↑.linenum;
 end;

procedure saveOutermostEnv; external;
procedure saveOutermostEnv;
 var menv: envheaderp;
 begin
 with debugPdbs[0]↑ do			(* use main process pdb *)
  begin
  menv := env;				(* save outermost environment *)
  level := 2;				(* so flushAll won't clobber it *)
  end;
 while menv↑.parent↑.parent <> nil do
  menv := menv↑.parent;			(* up to outermost environment *)
 flushOldEnvironments(0);
 singleThreadMode := false;		(* reset single thread (nowait) mode)
 eCurInt := curInt;			(* get new main process pdb *)
 debugPdbs[0] := eCurInt;
 with eCurInt↑ do
  begin
  spc := dprog↑.pcode↑.bcode;
  env := menv;				(* restore old environment *)
  sdef := dprog;
  linenum := 2;
  end;
 pcLine := 2;
 end;

(* initOuterBlock *)

procedure initOuterBlock (which:integer); external;
procedure initOuterBlock ;
 var i: integer; s: statementp; envhdr: envheaderp;
 begin
 flushOldEnvironments(0);
 eCurInt := curInt;
 debugPdbs[0] := eCurInt;
 with eCurInt↑ do
  begin
  spc := dprog;
  sdef := dprog;
  linenum := 2;
  end;
 pcLine := 2;
 s := dprog↑.pcode↑.bcode;
 s↑.bpt := true;				(* just deal with the BEGIN *)
 e3aInterp(0);					(* Initialize outermost block *)
 s↑.bpt := false;				(* done with bpt now *)
 while s↑.stype <> endtype do s := s↑.next;	(* find block END *)
 s↑.bpt := true;	(* so we'll never flush outer block's variables *)
 if eCurInt↑.env↑.parent = nil then		(* = sysEnv *)
   begin
   envhdr := newEheader;
   with envhdr↑ do
    begin
    parent := eCurInt↑.env;
    block := dprog↑.pcode;
    procp := false;
    for i := 0 to 4 do env[i] := nil;
    varcnt := 0;
    end;
   with eCurInt↑ do
    begin
    level := 1;
    env := envhdr;
    end;
   end;
 end;

(* Aux routine: setUpStmnt *)

procedure setUpStmnt(which: integer); external;
procedure setUpStmnt;
 var i: integer;
 begin
 lbufp := 0;
 cursor := 0;
 fieldNum := 1; 
 firstLine := 0;
 lastLine := 0;
 curLine := 0;
 cursorLine := 1;
 setCursor := false;
 setUp := true;
 setExpr := false;
 dontPrint := false;
 outFilep := false;
 findStmnt := nil;
 pcLine := 1;
 putStmnt(dprog,0,99);	(* figure out how long each statement is *)
 setUp := false;
 topDline := 0;
 botDline := -1;
 firstDline := 1;
 for i := 1 to maxLines do
  if lines[i] <> nil then
   begin
   relLine(lines[i]);			(* free up any old lines *)
   lines[i] := nil;
   end;
 for i := 1 to 20 do marks[i] := 0;
 nmarks := 0;
 for i := 1 to maxBpts do bpts[i] := nil;
 for i := 1 to maxTBpts do tbpts[i] := nil;
 nbpts := 0;
 ntbpts := 0;
 debugLevel := 0;
 for i := 1 to 10 do debugPdbs[i] := nil;
 collect := false;
 singleThreadMode := false;
 tSingleThreadMode := false;
 iSingleThreadMode := false;
 initOuterBlock(which);
 end;

(* makeOuterBlock *)

procedure makeOuterBlock; external;	(* Make initial BEGIN-END block *)
procedure makeOuterBlock;
 begin
 dprog := newStatement;
 with dprog↑ do
  begin
  stype := progtype;
  pcode := newStatement;
  with pcode↑ do
   begin
   stype := blocktype;
   blkid := nil;
   level := 1;
   numvars := 0;
   variables := nil;
   bparent := nil;
   end;
  appendEnd(pcode,pcode);
  with pcode↑ do bcode := next;
  errors := 0;
  appendEnd(dprog,pcode);
  end;
 setUpStmnt(0);		(* Tell it makeOuterBlock called it *)
 end;

(* aux routines: fileParse, writeProg, readProg *)

procedure fileParse(var fname: c20str); external;
procedure fileParse;
 var ip,i,j,k,prj,prg: integer; ch: char; b: boolean;

 function nextchar: char;
  begin
  if i <= maxChar then nextchar := upperCase(listing[i])
   else nextchar := ' ';
  i := i + 1;
  end;

 begin (* fileParse *)	(* A stripped down version for the 11 *)
 fname[1] := ' ';
 i := curChar;
 k := maxChar + 1;
 ip := 1;
 repeat 				(* Skip spaces *)
  ch := nextchar 
 until (ch <> ' ') or (i >= k);	
 b := true;
 while (ch <> ' ') and b do
  begin						(* parse file name *)
  if ip <= 20 then begin fname[ip] := ch; ip := ip + 1 end
   else 
    begin pp20L('Bad file name       ',13); ppLine; 
    b := false;
    end;
  ch := nextchar;
  end;
 for j := ip to 20 do fname[j] := ' ';		(* Space-fill the rest *)
 end;

procedure writeProg; external;
procedure writeProg;
 var i,j: integer; filnam: c20str; b: boolean; ch: ascii;
 begin
 fileParse(filnam);
 if filnam[1] <> ' ' then
   begin
   reset(outFile,filnam,'.AL',i);		(* see if file exists *)
   b := (i < 0);				(* does it? *)
   reset(outFile);				(* that's all we needed it for *)
   if not b then
     begin					(* yes - it does *)
     pp20('File already exists ',20); pp20('- type "Y" to overwr',20);
     pp10('ite it:   ',9); ppOutNow;
     i := 1;
     ch := exprEditor(dispHeight+ppOffset+1,1,ppBufp,ppBufp,i,0);
     if smartTerminal then			(* deboldify it *)
       outLine(dispHeight+ppOffset+1,ppBufp,ppBufp,i);
     for j := ppBufp to ppBufp+i-1 do ppBuf[j] := listing[j];
     j := ppBufp;
     ppBufp := ppBufp + i - 1;
     while (listing[j] = ' ') and (j < ppBufp + i - 1) do j := j + 1;
     b := (listing[j] = 'Y') or (listing[j] = chr(171B));	(* 'Y' or 'y' *)
     if not b then pp10(' - Aborted',10);
     ppLine;
     end;
   if b then
     begin
     rewrite(outFile,filnam,'.AL');		(* open file for output *)
     outFilep := true;
     firstLine := 0;
     lastLine := dprog↑.nlines + 1;
     curLine := 0;
     putStmnt(dprog,0,99);			(* write program out *)
     outFilep := false;
     break(outFile);	(* Maybe this will write out the stuff at the end.. *)
     close(outFile);				(* close file *)
     end;
   end
  else begin pp20L('Need a name for file',20); ppLine end;
 end;

(* Aux routines called by edit: getEcmd, doSetCmd *)

procedure getEcmd; external;
procedure getEcmd;
 begin
 getToken;			(* see what user wants us to do *)
 with curToken do
  if ttype = reswdtype then		(* may need to change to edit context *)
    if rtype = stmnttype then
      begin
      if stmnt = definetype then
	begin rtype := edittype; ed := definecmd end
       else if stmnt = cmtype then
	begin rtype := filtype; filler := ontype end
      end
     else if rtype = filtype then
      if filler = steptype then
	begin rtype := edittype; ed := stepcmd end
       else if filler = attype then
	begin rtype := edittype; ed := atcmd end
 end;

procedure doSetcmd;	 external;
procedure doSetcmd;	
 var svar: filtypes; b,onoff: boolean; arg: integer;

 function getNumericArg(default: integer): boolean;
  var b: boolean;
  begin
  with curToken do
   begin
   if ttype = constype then b := cons↑.ltype = svaltype
    else b := false;
   if b then arg := round(cons↑.s)		(* use specified argument *)
    else if endOfLine then 
     begin arg := default; b := true end	(* use default value *)
    else begin pp20L('Need a numeric arg  ',18); ppLine; end;
   end;
  getNumericArg := b;
  end;

 function getOnOff(default: boolean): boolean;
  var b: boolean;
  begin
  with curToken do
   begin
   b := (ttype = reswdtype) and (rtype = filtype) and
	((filler = ontype) or (filler = offtype));
   if b then onoff := filler = ontype
    else if endOfLine then
     begin onoff := default; b := true end	(* use default value *)
    else begin pp20L('Expecting ON or OFF ',19); ppLine; end;
   end;
  getOnOff := b;
  end;

 begin (* doSetCmd *)
 getEcmd;				(* see what we're setting *)
 with curToken do
  begin
  arg := 1;
  if (ttype = reswdtype) and (rtype = filtype) then svar := filler
   else if (ttype = reswdtype) and (rtype = stmnttype) and 
	   (stmnt = waittype) then begin svar := nowaittype; arg := -1 end
   else svar := defertype;		(* no good *)
  getEcmd;				(* see what we're setting it to *)
  case svar of
ppsizetype:   begin
	     b := getNumericArg(3);		(* default size is 3 *)
	     if b then setPPSize(arg);		(* set page printer size *)
	     end;
collecttype:  begin	(* see if we're collecting stmnts typed to interpreter *)
	     b := getOnOff(true);		(* default is collect *)
	     if b then collect := onoff;	(* set whether to collect *)
	     borderLines;			(* Redraw top line to show flag *)
	     end;
lextype:      begin
	     b := getNumericArg(1);		(* default is up one level *)
	     if b then 
	       begin (* *** ??? what do we do ??? *** *) end;
	     end;
nowaittype:   begin	(* arg = 1 for nowait, -1 for wait *)
	     b := getOnOff(true);
	     if arg < 0 then onoff := not onoff;
	     if b then
	       begin
	       singleThreadMode := onoff;
	       if (debugLevel < STLevel) or not tSingleThreadMode then
		 iSingleThreadMode := onoff;
	       end;
	     borderLines;			(* Redraw top line to show flag *)
	     end;
otherwise     begin pp20L('Bad SET request     ',15); ppLine end;
    end;
  if ttype = constype then relExpr(cons);
  end 
 end (* doSetCmd *);

(* Stupid little procedure to open the talking box: openTalk *)

(* This was put in this module, the last place you'd expect it, because	*)
(* IINIT used to do this but needed the runtimes for opening files.	*)
(* This gets called by ALMAIN *)

procedure openTalk; external;
procedure openTalk;
 begin
 rewrite(talk,'tt3:'); 			(* speech synthesizer is on tt3: *)
 writeln(talk,chr(5),'20P');  		(* Set up standard AL voice (a la jjc) *)
 end;