COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002		TITLE	CORDMP
C00005 ENDMK
C⊗;
	TITLE	CORDMP
INTERNAL SETLPT,RESLPT,CORDMP
EXTERNAL JOBDDT,JOBFF,$M


OPDEF TTCALL [51B8]

CORDMP:	MOVEI	1,LTLSTK
	MOVE	3,[POINT 7,STRING]
	SETZM	STRING
	MOVE	5,[XWD STRING,STRING+1]
	BLT	5,STREND
	MOVE	7,[POINT 7,[ASCIZ / $M+1!1000
 /]]
	PUSHJ	1,TYSET
	JRST	.-1
	TTCALL	3,[ASCIZ /LOWER BOUND = /]
	PUSHJ	1,TYI
	JRST	.-1
	MOVEI	5,"<"
	IDPB	5,3
	TTCALL	3,[ASCIZ /UPPER BOUND = /]
	PUSHJ	1,TYI
	JRST	.-1
	MOVE	7,[POINT 7,[ASCIZ />12121/]]
	PUSHJ	1,TYSET
	JRST	.-1
	TTCALL	3,[ASCIZ /MODE = /]
	PUSHJ	1,TYI
	JRST	.-1
	MOVE	7,[POINT 7,[ASCIZ /$N
POPJ 1,$X/]]
	PUSHJ	1,TYSET
	JRST	.-1

	MOVE	5,[POINT 7,STRING]
	MOVEM	5,$M-1
	JSP	10,STLPT
	PUSHJ	1,@JOBDDT

RETN:	JRST	RESLPT


TYSET:	ILDB	2,7
	JUMPE	2,CPOPJ
	IDPB	2,3
	jrst	tyset


TYI:	TTCALL	2
	CAIN	2,15
	JRST	DUN
	CAIN	2,177
	 JRST	 [TTCALL 3,[ASCIZ /\/]
		  LDB	2,3
		  TTCALL 1,2
		  SOS	3
		  REPEAT 4,<IBP  3
>
		  JRST	TYI
]

	IDPB	2,3
	POPJ	1,

DUN:	TTCALL	2
CPOPJ:	AOS	(1)
	POPJ	1,

SETLPT:	JSP	10,STLPT
	JRST	@JOBDDT

STLPT:	INIT	17,
	SIXBIT	/LPT/
	XWD	BHED,0
	JRST	[TTCALL 3,[ASCIZ /LPT NOT AVAILABLE, TYPE KEY TO RETRY
/]
		 TTCALL	2
		 JRST	STLPT]

	SETZM	WRRD+3
	ENTER	17,WRRD
	HALT
	MOVEI	BUFFAR
	MOVEM	JOBFF
	OUTBUF	17,2
	MOVEI	TYO
	MOVEM	$M-2
	JRST	(10)

RESLPT:	MOVEI	5,14
	MOVEI	1,LTLSTK
	PUSHJ	1,TYO
	SETZM	$M-2
	RELEASE	17,
	JRST	@JOBDDT

TYO:	SOSG	BHED+2
	OUTPUT	17,
	IDPB	5,BHED+1
	POPJ	3,

BHED:	BLOCK	3
WRRD:	'CORDMP'
	'TMP   '
	0
	0

BUFFAR:	BLOCK	2*=132

LTLSTK:	BLOCK	10


STRING:	BLOCK	40
STREND:	0

	END